This movie is Director 5 but Detlef Beyer <d.beyer@hermes.de> has replicated it in Director 6 and I have as well in this new version.

Here is the parent script:

property pId, pDestChar, pCurrChar, pTimes, pDone

-- =======================================================================
-- parent script:
-- ============= sneaker
--
-- Creates objects for each letter of the intended text
-- and randomizes on demand
-- =======================================================================

on new me, i, inText, N, flag
  -- the character position in the field
  set pID = i
  
  -- the intended letter when all is done
  set pDestChar = inText
  
  -- until then generate a random letter
  set pCurrChar = numToChar( 31 + random(94) )
  put pCurrChar into char pID of field "display" 
  
  -- the number of times to snekarize until we are done
  set pTimes = N
  
  -- a flag to indicate if we are done
  set pDone = 0
  return me
end

on stepFrame me
  if pDone then exit
  
  -- check if we have run the counter out
  if pTimes = 0 then
    
    -- yes, then set the done flag
    set pDone = 1
    
    -- put the intended letter into the proper place
    put pDestChar into char pID of field "display"
    
    -- As suggested by Martin Winkler 
    -- when the sneakering is done, change the color of the
    -- character as an indicator
    set the foreColor of char pID of field "display" to the foreColor of field "c"    
    kill me
        
  else
    -- decrement the counter
    set pTimes = pTimes  - 1
    
    -- generate another random character
    set pCurrChar = numToChar( 31 + random(94) )
    
    -- put the intended letter into the proper place 
    put pCurrChar into char pID of field "display"   
    
    -- Ok, I cannot explain this, but without this statement
    -- the shockwave version will adversely color text
    -- that is still scrambling
    -- to test it, see what happens when you comment out this line
    
   --  set the foreColor of char pID of field "display" = the foreColor of field "b"
  end if
end

on kill me
  deleteActor (script "main", me)
end